scripts - zygaena/hammerhead

root / base / usr / src / cmd / fm / scripts
scripts Plain Text 1416 lines 39.5 KB
#
# CDDL HEADER START
#
# The contents of this file are subject to the terms of the
# Common Development and Distribution License, Version 1.0 only
# (the "License").  You may not use this file except in compliance
# with the License.
#
# You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
# or http://www.opensolaris.org/os/licensing.
# See the License for the specific language governing permissions
# and limitations under the License.
#
# When distributing Covered Code, include this CDDL HEADER in each
# file and include the License file at usr/src/OPENSOLARIS.LICENSE.
# If applicable, add the following below this CDDL HEADER, with the
# fields enclosed by brackets "[]" replaced with your own identifying
# information: Portions Copyright [yyyy] [name of copyright owner]
#
# CDDL HEADER END
#
#
# Copyright 2004 Sun Microsystems, Inc.  All rights reserved.
# Use is subject to license terms.
#
#ident	"%Z%%M%	%I%	%E% SMI"

.KEEP_STATE:

include ../../Makefile.cmd

FMSCRIPTS = buildcode bustcode dictck
FMDSCRIPTS = fmsim
SCRIPTS = $(FMSCRIPTS) $(FMDSCRIPTS)
ROOTLIBFM = $(ROOT)/usr/lib/fm
ROOTLIBFMD = $(ROOT)/usr/lib/fm/fmd
ROOTSCRIPTS = $(FMSCRIPTS:%=$(ROOTLIBFM)/%) $(FMDSCRIPTS:%=$(ROOTLIBFMD)/%)

# Hammerhead: Use pattern rules instead of suffix rules to avoid
# conflicting with .pl rule in Makefile.master
%: %.pl
	$(RM) $@
	$(CAT) $< > $@
	$(CHMOD) +x $@

%: %.ksh
	$(RM) $@
	$(CAT) $< > $@
	$(CHMOD) +x $@

%: %.sh
	$(RM) $@
	$(CAT) $< > $@
	$(CHMOD) +x $@

all: $(SCRIPTS)

clobber:
	$(RM) $(SCRIPTS)

clean install_h lint _msg:

install: all $(ROOTSCRIPTS)

$(ROOTLIBFM)/% $(ROOTLIBFMD)/%: %
	$(INS.file)
#!/usr/bin/perl -w
#
# CDDL HEADER START
#
# The contents of this file are subject to the terms of the
# Common Development and Distribution License, Version 1.0 only
# (the "License").  You may not use this file except in compliance
# with the License.
#
# You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
# or http://www.opensolaris.org/os/licensing.
# See the License for the specific language governing permissions
# and limitations under the License.
#
# When distributing Covered Code, include this CDDL HEADER in each
# file and include the License file at usr/src/OPENSOLARIS.LICENSE.
# If applicable, add the following below this CDDL HEADER, with the
# fields enclosed by brackets "[]" replaced with your own identifying
# information: Portions Copyright [yyyy] [name of copyright owner]
#
# CDDL HEADER END
#
#
# ident	"%Z%%M%	%I%	%E% SMI"
#
# Copyright 2004 Sun Microsystems, Inc.  All rights reserved.
# Use is subject to license terms.
#
#
# buildcode -- Given a dictname and dictval, print the Message ID
#
# example: buildcode FMD 1
#  prints: FMD-8000-11
#
# usage: buildcode [-cvVt] dictname dictval
#
#	-c	trace checksumming process
#
#	-v	verbose, show how code is assembled
#
#	-V	even more verbose
#
#	-t	print table showing how codes work
#
# This is a completely separate implementation of how diagcodes
# are built (see libdiagcode, or PSARC/2003/323).  This separate
# implementation provides us a way to test libdiagcode and, since
# it is written in Perl, it provides a portable way to print Message
# IDs without building libdiagcode.  The event registry uses this
# script to display diagcodes.
#
# NOTE: This implementation may not support the full range of
# possible diagcodes (currently it only works up to 2^63-1 or
# 9223372036854775807 on most machines).
#
# XXX could probably fix the above limitation by using Math::BigInt.
#

use strict;
use integer;

use Getopt::Std;

use vars qw($opt_c $opt_v $opt_V $opt_t);

my $Myname = $0;	# save our name for error messages
$Myname =~ s,.*/,,;

$SIG{HUP} = $SIG{INT} = $SIG{TERM} = $SIG{__DIE__} = sub {
	die "$Myname: ERROR: @_";
};

# the alphabet used for diagcodes, indexed by 5-bit values
my $Alphabet = "0123456789ACDEFGHJKLMNPQRSTUVWXY";

# map codelen to the two-bit binary code size field in diagcode
my @Codesize = ( '00', '01', '10', '11' );

# map codelen to the sprintf format we use for dictval
my @Dictvalformat = ( '%021b', '%038b', '%055b', '%072b' );

# map codelen to number of data bits for dictval
my @Dictvalbits = ( 21, 38, 55, 72 );

# map codelen to the number of checksum bits used in diagcode
my @Csumbits = ( 5, 8, 11, 14 );

#
# buildcode -- build the Message ID from passed-in dictname & dictval
#
sub buildcode {
	my $dictname = shift;
	my $dictval = shift;
	my $csum = 0;
	my $i;
	my $bits;
	my $codelen;

	# force dictname to upper case
	$dictname = uc($dictname);

	# check for integer overflow
	die "dictval $dictval converts to " . sprintf("%d", $dictval) .
	    " (integer overflow?)\n" if sprintf("%d", $dictval) ne $dictval;

	# largest possible dictval is (2^21 + 2^38 + 2^55 + 2^72-1)
	# XXX the following check itself causes integer overflow, but
	# XXX disabling it doesn't matter for now since the above check
	# XXX tops out at 2^63-1
	#die "dictval $dictval too big\n" if $dictval > 4722402511941544181759;

	print "   Dictname: \"$dictname\"\n" if $opt_v;

	# using sprintf will show conversion/overflow errors
	print "    Dictval: " . sprintf("%d", $dictval) . ": " if $opt_v;

	# determine which size Message ID to use
	if ($dictval < 2097152) {
		$codelen = 0;
		print "below 2^21\n" if $opt_v;
		if ($opt_V) {
			print "   Format 0: " .
			    "DICT-XXXX-XX\n";
			print "              2 bits code type\n";
			print "              2 bits size\n";
			print "             21 bits dictval\n";
			print "              8 bits checksum\n";
		}
	} elsif (274880004096 < 0) {
		# this prevents errors on some versions of Linux
		die "dictval $dictval too big for Perl on this machine\n";
	} elsif ($dictval < 274880004096) {
		$codelen = 1;
		$dictval -= 2097152;
		print "above 2^21-1, below 2^38-1\n" if $opt_v;
		if ($opt_V) {
			print "   Format 1: " .
			    "DICT-XXXX-XXXX-XX\n";
			print "              2 bits code type\n";
			print "              2 bits size\n";
			print "             38 bits dictval " .
			    "(adjusted dictval $dictval)\n";
			print "              8 bits checksum\n";
		}
	} elsif (36029071898968064 < 0) {
		# this prevents errors on some versions of Linux
		die "dictval $dictval too big for Perl on this machine\n";
	} elsif ($dictval < 36029071898968064) {
		$codelen = 2;
		$dictval -= 274880004096;
		print "above 2^38-1, below 2^55-1\n" if $opt_v;
		if ($opt_V) {
			print "   Format 2: " .
			    "DICT-XXXX-XXXX-XXXX-XX\n";
			print "              2 bits code type\n";
			print "              2 bits size\n";
			print "             55 bits dictval " .
			    "(adjusted dictval $dictval)\n";
			print "             11 bits checksum\n";
		}
	} else {
		$codelen = 3;
		$dictval -= 36029071898968064;
		print "above 2^55-1, below 2^72-1\n" if $opt_v;
		if ($opt_V) {
			print "   Format 3: " .
			    "DICT-XXXX-XXXX-XXXX-XXXX-XX\n";
			print "              2 bits code type\n";
			print "              2 bits size\n";
			print "             72 bits dictval " .
			    "(adjusted dictval $dictval)\n";
			print "             14 bits checksum\n";
		}
	}

	# first run dictname through checksum
	foreach $i (unpack('C*', $dictname)) {
		$csum = crc($csum, $i);
	}

	# 2 bit code type, set to 01
	print "  Code type: 01\n" if $opt_v;
	$bits = "01";

	# 2 bit size field
	print "  Code size: " . $Codesize[$codelen] . "\n" if $opt_v;
	$bits .= $Codesize[$codelen];

	# data bits of the dictval
	$dictval = sprintf($Dictvalformat[$codelen], $dictval);
	print "    Dictval: $dictval\n" if $opt_v;
	die "binary dictval is " . length($dictval) .
	    " bits instead of the expected $Dictvalbits[$codelen]\n"
	    if length($dictval) != $Dictvalbits[$codelen];
	$bits .= $dictval;

	# csum bits, zeroed
	$bits .= '0' x $Csumbits[$codelen];

	# compute csum by taking 5 bits at a time from left to right
	my $bitscopy = $bits;
	while ($bitscopy =~ /(.....)/) {
		$csum = crc($csum, oct('0b' . $1));
		$bitscopy =~ s/.....//;
	}

	printf("CRC: 0x%x\n", $csum) if $opt_c;

	# change the zeroed csum bits to the computed value, masking
	# the computed checksum down to the appropriate number of bits
	print "   Checksum: " . substr(sprintf("%014b", $csum),
	    - $Csumbits[$codelen],  $Csumbits[$codelen]) . "\n" if $opt_v;
	substr($bits, - $Csumbits[$codelen],  $Csumbits[$codelen]) =
	    substr(sprintf("%b", $csum),
	    - $Csumbits[$codelen],  $Csumbits[$codelen]);

	# convert to diagcode alphabet, 5 bits at a time from left to right
	print "  Converted:\n" if $opt_V;
	my $x;
	while ($bits =~ /(.....)/) {
		print "             $1 = " .
		    substr($Alphabet, oct('0b' . $1), 1) . "\n" if $opt_V;
		$x .= substr($Alphabet, oct('0b' . $1), 1);
		$bits =~ s/.....//;
	}

	# insert the dashes at the appropriate points
	$x =~ s/(..)$/-$1/;
	$x =~ s/([^-]{4})([^-])/$1-$2/;
	$x =~ s/([^-]{4})([^-])/$1-$2/;
	$x =~ s/([^-]{4})([^-])/$1-$2/;
	$x =~ s/([^-]{4})([^-])/$1-$2/;

	return "$dictname-$x";
}

# table used by crc()
my @Crctab = (
0x00000000,
0x04C11DB7, 0x09823B6E, 0x0D4326D9, 0x130476DC, 0x17C56B6B,
0x1A864DB2, 0x1E475005, 0x2608EDB8, 0x22C9F00F, 0x2F8AD6D6,
0x2B4BCB61, 0x350C9B64, 0x31CD86D3, 0x3C8EA00A, 0x384FBDBD,
0x4C11DB70, 0x48D0C6C7, 0x4593E01E, 0x4152FDA9, 0x5F15ADAC,
0x5BD4B01B, 0x569796C2, 0x52568B75, 0x6A1936C8, 0x6ED82B7F,
0x639B0DA6, 0x675A1011, 0x791D4014, 0x7DDC5DA3, 0x709F7B7A,
0x745E66CD, 0x9823B6E0, 0x9CE2AB57, 0x91A18D8E, 0x95609039,
0x8B27C03C, 0x8FE6DD8B, 0x82A5FB52, 0x8664E6E5, 0xBE2B5B58,
0xBAEA46EF, 0xB7A96036, 0xB3687D81, 0xAD2F2D84, 0xA9EE3033,
0xA4AD16EA, 0xA06C0B5D, 0xD4326D90, 0xD0F37027, 0xDDB056FE,
0xD9714B49, 0xC7361B4C, 0xC3F706FB, 0xCEB42022, 0xCA753D95,
0xF23A8028, 0xF6FB9D9F, 0xFBB8BB46, 0xFF79A6F1, 0xE13EF6F4,
0xE5FFEB43, 0xE8BCCD9A, 0xEC7DD02D, 0x34867077, 0x30476DC0,
0x3D044B19, 0x39C556AE, 0x278206AB, 0x23431B1C, 0x2E003DC5,
0x2AC12072, 0x128E9DCF, 0x164F8078, 0x1B0CA6A1, 0x1FCDBB16,
0x018AEB13, 0x054BF6A4, 0x0808D07D, 0x0CC9CDCA, 0x7897AB07,
0x7C56B6B0, 0x71159069, 0x75D48DDE, 0x6B93DDDB, 0x6F52C06C,
0x6211E6B5, 0x66D0FB02, 0x5E9F46BF, 0x5A5E5B08, 0x571D7DD1,
0x53DC6066, 0x4D9B3063, 0x495A2DD4, 0x44190B0D, 0x40D816BA,
0xACA5C697, 0xA864DB20, 0xA527FDF9, 0xA1E6E04E, 0xBFA1B04B,
0xBB60ADFC, 0xB6238B25, 0xB2E29692, 0x8AAD2B2F, 0x8E6C3698,
0x832F1041, 0x87EE0DF6, 0x99A95DF3, 0x9D684044, 0x902B669D,
0x94EA7B2A, 0xE0B41DE7, 0xE4750050, 0xE9362689, 0xEDF73B3E,
0xF3B06B3B, 0xF771768C, 0xFA325055, 0xFEF34DE2, 0xC6BCF05F,
0xC27DEDE8, 0xCF3ECB31, 0xCBFFD686, 0xD5B88683, 0xD1799B34,
0xDC3ABDED, 0xD8FBA05A, 0x690CE0EE, 0x6DCDFD59, 0x608EDB80,
0x644FC637, 0x7A089632, 0x7EC98B85, 0x738AAD5C, 0x774BB0EB,
0x4F040D56, 0x4BC510E1, 0x46863638, 0x42472B8F, 0x5C007B8A,
0x58C1663D, 0x558240E4, 0x51435D53, 0x251D3B9E, 0x21DC2629,
0x2C9F00F0, 0x285E1D47, 0x36194D42, 0x32D850F5, 0x3F9B762C,
0x3B5A6B9B, 0x0315D626, 0x07D4CB91, 0x0A97ED48, 0x0E56F0FF,
0x1011A0FA, 0x14D0BD4D, 0x19939B94, 0x1D528623, 0xF12F560E,
0xF5EE4BB9, 0xF8AD6D60, 0xFC6C70D7, 0xE22B20D2, 0xE6EA3D65,
0xEBA91BBC, 0xEF68060B, 0xD727BBB6, 0xD3E6A601, 0xDEA580D8,
0xDA649D6F, 0xC423CD6A, 0xC0E2D0DD, 0xCDA1F604, 0xC960EBB3,
0xBD3E8D7E, 0xB9FF90C9, 0xB4BCB610, 0xB07DABA7, 0xAE3AFBA2,
0xAAFBE615, 0xA7B8C0CC, 0xA379DD7B, 0x9B3660C6, 0x9FF77D71,
0x92B45BA8, 0x9675461F, 0x8832161A, 0x8CF30BAD, 0x81B02D74,
0x857130C3, 0x5D8A9099, 0x594B8D2E, 0x5408ABF7, 0x50C9B640,
0x4E8EE645, 0x4A4FFBF2, 0x470CDD2B, 0x43CDC09C, 0x7B827D21,
0x7F436096, 0x7200464F, 0x76C15BF8, 0x68860BFD, 0x6C47164A,
0x61043093, 0x65C52D24, 0x119B4BE9, 0x155A565E, 0x18197087,
0x1CD86D30, 0x029F3D35, 0x065E2082, 0x0B1D065B, 0x0FDC1BEC,
0x3793A651, 0x3352BBE6, 0x3E119D3F, 0x3AD08088, 0x2497D08D,
0x2056CD3A, 0x2D15EBE3, 0x29D4F654, 0xC5A92679, 0xC1683BCE,
0xCC2B1D17, 0xC8EA00A0, 0xD6AD50A5, 0xD26C4D12, 0xDF2F6BCB,
0xDBEE767C, 0xE3A1CBC1, 0xE760D676, 0xEA23F0AF, 0xEEE2ED18,
0xF0A5BD1D, 0xF464A0AA, 0xF9278673, 0xFDE69BC4, 0x89B8FD09,
0x8D79E0BE, 0x803AC667, 0x84FBDBD0, 0x9ABC8BD5, 0x9E7D9662,
0x933EB0BB, 0x97FFAD0C, 0xAFB010B1, 0xAB710D06, 0xA6322BDF,
0xA2F33668, 0xBCB4666D, 0xB8757BDA, 0xB5365D03, 0xB1F740B4
);

#
# crc -- calculate a CRC using passed-in starting value & additional data
#
sub crc {
	my $cval = shift;
	my $val = shift;

	printf("crc(0x%08x, 0x%x)\n", $cval, $val) if $opt_c;

	return (($cval<<8) ^ $Crctab[((($cval>>24) & 0xff) ^ $val) & 0xff]);
}

#
# usage -- print a usage message and exit
#
sub usage {
	my $msg = shift;

	warn "$Myname: $msg\n" if defined($msg);
	warn "usage: $Myname [-cvVt] dictname dictval\n";
	exit 1;
}

#
# the "main" for this script...
#
getopts('cvVt') or usage;

$opt_v = 1 if $opt_V;	# big V implies small v

# even before printing any usage messages, spew table if asked
if ($opt_t) {
	print <<EOF;
                        TABLE OF TYPE 1 DIAGCODE FORMATS

Format 0: "dict-XXXX-XX",                21 data bits,  5 checksum bits
                 0 through                2097151 (2^21-1)


Format 1: "dict-XXXX-XXXX-XX",           38 data bits,  8 checksum bits
           2097152 through           274880004095 (2^21 + 2^38-1)


Format 2: "dict-XXXX-XXXX-XXXX-XX",      55 data bits, 11 checksum bits
      274880004096 through      36029071898968063 (2^21 + 2^38 + 2^55-1)


Format 3: "dict-XXXX-XXXX-XXXX-XXXX-XX", 72 data bits, 14 checksum bits
 36029071898968064 through 4722402511941544181759 (2^21 + 2^38 + 2^55 + 2^72-1)

Code alphabet is: $Alphabet

EOF
}

my $dictname = shift;
my $dictval = shift;
usage unless defined($dictname) && defined($dictval);
usage if @ARGV;
if ($opt_v) {
	print "SUNW-MSG-ID: " . buildcode($dictname, $dictval) . "\n";
} else {
	print buildcode($dictname, $dictval) . "\n";
}
exit 0;
#!/usr/bin/perl -w
#
# CDDL HEADER START
#
# The contents of this file are subject to the terms of the
# Common Development and Distribution License, Version 1.0 only
# (the "License").  You may not use this file except in compliance
# with the License.
#
# You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
# or http://www.opensolaris.org/os/licensing.
# See the License for the specific language governing permissions
# and limitations under the License.
#
# When distributing Covered Code, include this CDDL HEADER in each
# file and include the License file at usr/src/OPENSOLARIS.LICENSE.
# If applicable, add the following below this CDDL HEADER, with the
# fields enclosed by brackets "[]" replaced with your own identifying
# information: Portions Copyright [yyyy] [name of copyright owner]
#
# CDDL HEADER END
#
#
# ident	"%Z%%M%	%I%	%E% SMI"
#
# Copyright 2004 Sun Microsystems, Inc.  All rights reserved.
# Use is subject to license terms.
#
#
# bustcode -- Given a Message ID, bust it up into fields and print them
#
# usage: bustcode [-cq] message-id
#
#	-c	trace checksumming process
#
#	-q	quiet mode, only output dictname and dictval
#
# This script is used for testing & debugging of libdiagcode
# (PSARC/2003/323).
#
# NOTE: This implementation may not support the full range of
# possible diagcodes (currently it only works up to 2^63-1 or
# 9223372036854775807 on most machines).
#
# XXX could probably fix the above limitation by using Math::BigInt.
#

use strict;
use integer;

use Getopt::Std;

use vars qw($opt_c $opt_q);

my $Myname = $0;	# save our name for error messages
$Myname =~ s,.*/,,;

$SIG{HUP} = $SIG{INT} = $SIG{TERM} = $SIG{__DIE__} = sub {
	die "$Myname: ERROR: @_";
};

# the alphabet used for diagcodes, indexed by 5-bit values
my $Alphabet = "0123456789ACDEFGHJKLMNPQRSTUVWXY";

# map codelen to the two-bit binary code size field in diagcode
my @Codesize = ( '00', '01', '10', '11' );

# map codelen to the sprintf format we use for dictval
my @Dictvalformat = ( '%021b', '%038b', '%055b', '%072b' );

# map codelen to number of data bits for dictval
my @Dictvalbits = ( 21, 38, 55, 72 );

# map codelen to the number of checksum bits used in diagcode
my @Csumbits = ( 5, 8, 11, 14 );

#
# bustcode -- bust up a Message ID into fields
#
sub bustcode {
	my $id = shift;
	my $dictname;
	my $xpart;
	my $dictval;
	my $csum = 0;
	my $csumfromcode;
	my $bits;
	my $codelen;
	my $x;
	my $i;

	die "\"$id\" malformed Message ID\n"
	    unless $id =~ /^(\w+)-(([a-zA-Z0-9]{4}-){1,4}[a-zA-Z0-9]{2})$/;

	$dictname = $1;
	$xpart = $2;

	if ($xpart =~ /(([a-zA-Z0-9]{4}-){4}[a-zA-Z0-9]{2})/) {
		$codelen = 3;
	} elsif ($xpart =~ /(([a-zA-Z0-9]{4}-){3}[a-zA-Z0-9]{2})/) {
		$codelen = 2;
	} elsif ($xpart =~ /(([a-zA-Z0-9]{4}-){2}[a-zA-Z0-9]{2})/) {
		$codelen = 1;
	} elsif ($xpart =~ /(([a-zA-Z0-9]{4}-){1}[a-zA-Z0-9]{2})/) {
		$codelen = 0;
	} else {
		die "internal error: code len patterns are wrong\n";
	}
	print "             Bust up code: \"$id\" (format $codelen)\n"
	    unless $opt_q;

	$dictname = uc($dictname);
	$xpart = uc($xpart);
	$xpart =~ s/B/8/g;
	$xpart =~ s/I/1/g;
	$xpart =~ s/O/0/g;
	$xpart =~ s/Z/2/g;

	unless ($opt_q) {
		print "After alphabet correction: \"$dictname-$xpart\"\n"
		    if $id ne "$dictname-$xpart";

		print "          Dictionary name: \"$dictname\"\n";
	}

	# first run dictname through checksum
	foreach $i (unpack('C*', $dictname)) {
		$csum = crc($csum, $i);
	}

	# convert xpart to binary number (really a string of [01])
	print "               Conversion:\n" unless $opt_q;
	while ($xpart =~ /(.)/) {
		$x = $1;
		$xpart =~ s/.//;
		next if $x eq '-';
		$i = 0;
		while (1) {
			
			die "illegal character in Message ID: \"$x\"\n"
			    unless $i < length($Alphabet);

			last if $x eq substr($Alphabet, $i, 1);
			$i++;
		}
		print "                           $x = " .
		    sprintf('%05b', $i) . "\n" unless $opt_q;
		$bits .= sprintf('%05b', $i);
	}

	die "no code type in bits \"$bits\"\n"
	    unless $bits =~ /^(..)/;
	print "         2 bits code type: $1\n" unless $opt_q;
	die "unrecognized code type (must be 01)\n" unless $1 eq '01';

	die "no code length in bits \"$bits\"\n"
	    unless $bits =~ /^..(..)/;
	print "              2 bits size: $1\n" unless $opt_q;
	die "size field doesn't match format\n"
	    unless oct('0b' . $1) == $codelen;

	# extract the dictval (skip 4 bits for code type & size fields)
	$dictval = substr($bits, 4, $Dictvalbits[$codelen]);
	die "no dictval in bits \"$bits\"\n"
	    unless length($dictval) == $Dictvalbits[$codelen];
	print "          " . sprintf('%2d', $Dictvalbits[$codelen]) .
	    " bits dictval: $dictval\n" unless $opt_q;
	$dictval = bintoi($dictval);
	print "          Decimal dictval: $dictval\n" unless $opt_q;

	# check for integer overflow
	warn "$Myname: ERROR: dictval is negative (integer overflow)\n"
		if $dictval < 0;

	if ($codelen == 1) {
		print "      Add format 1 offset: 2097152\n" unless $opt_q;
		$dictval += 2097152;
		print "         Adjusted dictval: $dictval\n" unless $opt_q;
	} elsif ($codelen == 2) {
		print "      Add format 2 offset: 274880004096\n" unless $opt_q;
		$dictval += 274880004096;
		print "         Adjusted dictval: $dictval\n" unless $opt_q;
	} elsif ($codelen == 3) {
		print "      Add format 3 offset: 36029071898968064\n"
		    unless $opt_q;
		$dictval += 36029071898968064;
		print "         Adjusted dictval: $dictval\n" unless $opt_q;
	}

	# check for integer overflow
	warn "$Myname: ERROR: dictval $dictval converts to " .
	    sprintf("%d", $dictval) . " (integer overflow?)\n"
	    if sprintf("%d", $dictval) ne $dictval;

	# save the checksum given to us in the code
	$csumfromcode =
	    substr($bits, - $Csumbits[$codelen],  $Csumbits[$codelen]);
	die "no checksum in bits \"$bits\"\n"
	    unless length($csumfromcode) == $Csumbits[$codelen];

	# zero the checksum for our calculation
	substr($bits, - $Csumbits[$codelen],  $Csumbits[$codelen]) =
	    '0' x $Csumbits[$codelen];

	# compute csum by taking 5 bits at a time from left to right
	my $bitscopy = $bits;
	while ($bitscopy =~ /(.....)/) {
		$csum = crc($csum, oct('0b' . $1));
		$bitscopy =~ s/.....//;
	}

	printf("CRC: 0x%x\n", $csum) if $opt_c;

	# changed the zeroed csum bits to the computed value, masking
	# the computed checksum down to the appropriate number of bits
	unless ($opt_q) {
		print "         " . sprintf('%2d', $Csumbits[$codelen]) .
		    " bits checksum: ";
		print "$csumfromcode ";
	}
	if ($csumfromcode eq substr(sprintf('%014b', $csum),
	    - $Csumbits[$codelen],  $Csumbits[$codelen])) {
		print "(correct)\n" unless $opt_q;
	} else {
		if ($opt_q) {
			warn "$Myname: ERROR: incorrect checksum " .
			    "($csumfromcode should be " .
			    substr(sprintf('%014b', $csum),
			    - $Csumbits[$codelen],
			    $Csumbits[$codelen]) . ")\n";
		} else {
			print "INCORRECT (should be " .
			    substr(sprintf('%014b', $csum),
			    - $Csumbits[$codelen],
			    $Csumbits[$codelen]) . ")\n";
		}
	}

	return "$dictname $dictval";
}

#
# bintoi -- convert string of binary digits to a number
#
# XXX there's got to be a better way to do this, but using oct()
# XXX causes a warning about non-portable binary numbers...
#
sub bintoi {
	my $bits = shift;
	my $mul = 1;
	my $retval = 0;

	while ($bits =~ /(.)$/) {
		$retval += $mul if $1 eq '1';
		$mul *= 2;
		$bits =~ s/.$//;
	}

	return $retval;
}

# table used by crc()
my @Crctab = (
0x00000000,
0x04C11DB7, 0x09823B6E, 0x0D4326D9, 0x130476DC, 0x17C56B6B,
0x1A864DB2, 0x1E475005, 0x2608EDB8, 0x22C9F00F, 0x2F8AD6D6,
0x2B4BCB61, 0x350C9B64, 0x31CD86D3, 0x3C8EA00A, 0x384FBDBD,
0x4C11DB70, 0x48D0C6C7, 0x4593E01E, 0x4152FDA9, 0x5F15ADAC,
0x5BD4B01B, 0x569796C2, 0x52568B75, 0x6A1936C8, 0x6ED82B7F,
0x639B0DA6, 0x675A1011, 0x791D4014, 0x7DDC5DA3, 0x709F7B7A,
0x745E66CD, 0x9823B6E0, 0x9CE2AB57, 0x91A18D8E, 0x95609039,
0x8B27C03C, 0x8FE6DD8B, 0x82A5FB52, 0x8664E6E5, 0xBE2B5B58,
0xBAEA46EF, 0xB7A96036, 0xB3687D81, 0xAD2F2D84, 0xA9EE3033,
0xA4AD16EA, 0xA06C0B5D, 0xD4326D90, 0xD0F37027, 0xDDB056FE,
0xD9714B49, 0xC7361B4C, 0xC3F706FB, 0xCEB42022, 0xCA753D95,
0xF23A8028, 0xF6FB9D9F, 0xFBB8BB46, 0xFF79A6F1, 0xE13EF6F4,
0xE5FFEB43, 0xE8BCCD9A, 0xEC7DD02D, 0x34867077, 0x30476DC0,
0x3D044B19, 0x39C556AE, 0x278206AB, 0x23431B1C, 0x2E003DC5,
0x2AC12072, 0x128E9DCF, 0x164F8078, 0x1B0CA6A1, 0x1FCDBB16,
0x018AEB13, 0x054BF6A4, 0x0808D07D, 0x0CC9CDCA, 0x7897AB07,
0x7C56B6B0, 0x71159069, 0x75D48DDE, 0x6B93DDDB, 0x6F52C06C,
0x6211E6B5, 0x66D0FB02, 0x5E9F46BF, 0x5A5E5B08, 0x571D7DD1,
0x53DC6066, 0x4D9B3063, 0x495A2DD4, 0x44190B0D, 0x40D816BA,
0xACA5C697, 0xA864DB20, 0xA527FDF9, 0xA1E6E04E, 0xBFA1B04B,
0xBB60ADFC, 0xB6238B25, 0xB2E29692, 0x8AAD2B2F, 0x8E6C3698,
0x832F1041, 0x87EE0DF6, 0x99A95DF3, 0x9D684044, 0x902B669D,
0x94EA7B2A, 0xE0B41DE7, 0xE4750050, 0xE9362689, 0xEDF73B3E,
0xF3B06B3B, 0xF771768C, 0xFA325055, 0xFEF34DE2, 0xC6BCF05F,
0xC27DEDE8, 0xCF3ECB31, 0xCBFFD686, 0xD5B88683, 0xD1799B34,
0xDC3ABDED, 0xD8FBA05A, 0x690CE0EE, 0x6DCDFD59, 0x608EDB80,
0x644FC637, 0x7A089632, 0x7EC98B85, 0x738AAD5C, 0x774BB0EB,
0x4F040D56, 0x4BC510E1, 0x46863638, 0x42472B8F, 0x5C007B8A,
0x58C1663D, 0x558240E4, 0x51435D53, 0x251D3B9E, 0x21DC2629,
0x2C9F00F0, 0x285E1D47, 0x36194D42, 0x32D850F5, 0x3F9B762C,
0x3B5A6B9B, 0x0315D626, 0x07D4CB91, 0x0A97ED48, 0x0E56F0FF,
0x1011A0FA, 0x14D0BD4D, 0x19939B94, 0x1D528623, 0xF12F560E,
0xF5EE4BB9, 0xF8AD6D60, 0xFC6C70D7, 0xE22B20D2, 0xE6EA3D65,
0xEBA91BBC, 0xEF68060B, 0xD727BBB6, 0xD3E6A601, 0xDEA580D8,
0xDA649D6F, 0xC423CD6A, 0xC0E2D0DD, 0xCDA1F604, 0xC960EBB3,
0xBD3E8D7E, 0xB9FF90C9, 0xB4BCB610, 0xB07DABA7, 0xAE3AFBA2,
0xAAFBE615, 0xA7B8C0CC, 0xA379DD7B, 0x9B3660C6, 0x9FF77D71,
0x92B45BA8, 0x9675461F, 0x8832161A, 0x8CF30BAD, 0x81B02D74,
0x857130C3, 0x5D8A9099, 0x594B8D2E, 0x5408ABF7, 0x50C9B640,
0x4E8EE645, 0x4A4FFBF2, 0x470CDD2B, 0x43CDC09C, 0x7B827D21,
0x7F436096, 0x7200464F, 0x76C15BF8, 0x68860BFD, 0x6C47164A,
0x61043093, 0x65C52D24, 0x119B4BE9, 0x155A565E, 0x18197087,
0x1CD86D30, 0x029F3D35, 0x065E2082, 0x0B1D065B, 0x0FDC1BEC,
0x3793A651, 0x3352BBE6, 0x3E119D3F, 0x3AD08088, 0x2497D08D,
0x2056CD3A, 0x2D15EBE3, 0x29D4F654, 0xC5A92679, 0xC1683BCE,
0xCC2B1D17, 0xC8EA00A0, 0xD6AD50A5, 0xD26C4D12, 0xDF2F6BCB,
0xDBEE767C, 0xE3A1CBC1, 0xE760D676, 0xEA23F0AF, 0xEEE2ED18,
0xF0A5BD1D, 0xF464A0AA, 0xF9278673, 0xFDE69BC4, 0x89B8FD09,
0x8D79E0BE, 0x803AC667, 0x84FBDBD0, 0x9ABC8BD5, 0x9E7D9662,
0x933EB0BB, 0x97FFAD0C, 0xAFB010B1, 0xAB710D06, 0xA6322BDF,
0xA2F33668, 0xBCB4666D, 0xB8757BDA, 0xB5365D03, 0xB1F740B4
);

#
# crc -- calculate a CRC using passed-in starting value & additional data
#
sub crc {
	my $cval = shift;
	my $val = shift;

	printf("crc(0x%08x, 0x%x)\n", $cval, $val) if $opt_c;

	return (($cval<<8) ^ $Crctab[((($cval>>24) & 0xff) ^ $val) & 0xff]);
}

#
# usage -- print a usage message and exit
#
sub usage {
	my $msg = shift;

	warn "$Myname: $msg\n" if defined($msg);
	warn "usage: $Myname [-q] message-id\n";
	exit 1;
}

#
# the "main" for this script...
#
getopts('cq') or usage;

my $id = shift || usage;
usage if @ARGV;
if ($opt_q) {
	print bustcode($id) . "\n";
} else {
	bustcode($id);
}
exit 0;
#!/usr/bin/perl -w
#
# CDDL HEADER START
#
# The contents of this file are subject to the terms of the
# Common Development and Distribution License (the "License").
# You may not use this file except in compliance with the License.
#
# You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
# or http://www.opensolaris.org/os/licensing.
# See the License for the specific language governing permissions
# and limitations under the License.
#
# When distributing Covered Code, include this CDDL HEADER in each
# file and include the License file at usr/src/OPENSOLARIS.LICENSE.
# If applicable, add the following below this CDDL HEADER, with the
# fields enclosed by brackets "[]" replaced with your own identifying
# information: Portions Copyright [yyyy] [name of copyright owner]
#
# CDDL HEADER END
#
# Copyright (c) 2004, 2010, Oracle and/or its affiliates. All rights reserved.
#
#
# dictck -- Sanity check a .dict file and optionally the corresponding .po file
#
# example: dickck FMD.dict FMD.po
#
# usage: dickck [-vp] [ -b buildcode ] dictfile [ pofile ]
#
#	-b	specify location of "buildcode" command
#
#	-p	print a .po file template to stdout, based on dictfile given
#
#	-v	verbose, show how code is assembled
#
# Note: this program requires the "buildcode" program in your search path.
#

use strict;

use Getopt::Std;

use vars qw($opt_b $opt_p $opt_v);

my $Myname = $0;	# save our name for error messages
$Myname =~ s,.*/,,;

$SIG{HUP} = $SIG{INT} = $SIG{TERM} = $SIG{__DIE__} = sub {
	# although fatal, we prepend "WARNING:" to make sure the
	# commonly-used "nightly" script flags this as lint on the .dict file
	die "$Myname: WARNING: @_";
};

#
# Category 1 event classes
#
my @cat1ev = qw(fault defect upset ereport list ireport);

#
# usage -- print a usage message and exit
#
sub usage {
	my $msg = shift;

	warn "$Myname: $msg\n" if defined($msg);
	warn "usage: $Myname [-pv] [ -b buildcode ] dictfile [ pofile ]\n";
	exit 1;
}

my %keys2val;
my %val2keys;
my %code2val;

my $buildcode = 'buildcode';

#
# the "main" for this script...
#
getopts('b:pv') or usage;

my $dictfile = shift;
my $pofile = shift;
usage unless defined($dictfile);
usage if @ARGV;
$buildcode = $opt_b if defined($opt_b);
dodict($dictfile);
dopo($pofile) if defined($pofile);
exit 0;

#
# dodict -- load up a .dict file, sanity checking it as we go
#
sub dodict {
	my $name = shift;
	my $dname;
	my $line = 0;
	my $lhs;
	my $rhs;
	my %props;
	my $maxkey = 1;

	if ($name =~ m,([^/]+)\.dict$,) {
		$dname = $1;
	} else {
		die "dictname \"$name\" not something.dict as expected\n";
	}

	open(F, $name) or die "$name: $!\n";
	print "parsing \"$name\"\n" if $opt_v;
	while (<F>) {
		$line++;
		next if /^\s*#/;
		chomp;
		next if /^\s*$/;
		die "$name:$line: first non-comment line must be FMDICT line\n"
		    unless /^FMDICT:/;
		print "FMDICT keyword found on line $line\n" if $opt_v;
		s/FMDICT:\s*//;
		my $s = $_;
		while ($s =~ /^\s*([^=\s]+)(.*)$/) {
			$lhs = $1;
			$rhs = "";
			$s = $+;
			if ($s =~ /^\s*=\s*(.*)$/) {
				$s = $+;
				die "$name:$line: property \"$lhs\" incomplete\n"
				    unless $s ne "";
			}
			if ($s =~ /^"((?:[^"]|\\")*)"(.*)$/) {
				$s = $+;
				$rhs = $1;
			} else {
				$s =~ /^([^\s]*)(.*)$/;
				$s = $+;
				$rhs = $1;
			}
			$rhs =~ s/\\(.)/dobs($1)/ge;
			$props{$lhs} = $rhs;
			print "property \"$lhs\" value \"$rhs\"\n" if $opt_v;
		}
		last;
	}
	# check for required headers
	die "$name: no version property in header\n"
	    unless defined($props{'version'});
	die "$name: no name property in header\n"
	    unless defined($props{'name'});
	die "$name: no maxkey property in header\n"
	    unless defined($props{'maxkey'});

	# check version
	die "$name:$line: unexpected version: \"$props{'version'}\"\n"
	    unless $props{'version'} eq "1";

	# check name
	die "$name:$line: name \"$props{'name'}\" doesn't match \"$dname\" from filename\n"
	    unless $props{'name'} eq $dname;

	# check format of maxkey (value checked later)
	die "$name:$line: maxkey property must be a number\n"
	    unless $props{'maxkey'} =~ /^\d+$/;

	# check for old bits property
	die "$name: obsolete \"bits\" property found in header\n"
	    if defined($props{'bits'});

	# parse entries
	while (<F>) {
		$line++;
		chomp;
		s/#.*//;
		next if /^\s*$/;
		die "$name:$line: malformed entry\n"
		    unless /^([^=]+)=(\d+)$/;
		$lhs = $1;
		$rhs = $2;

		# make sure keys are sorted
		my $elhs = join(' ', sort split(/\s/, $lhs));
		die "$name:$line: keys not in expected format of:\n" .
		    "    \"$elhs\"\n"
		    unless $elhs eq $lhs;

		# check for duplicate or unexpected keys
		my %keys;
		my $cat1pat = join('|', @cat1ev);
		foreach my $e (split(/\s/, $lhs)) {
			die "$name:$line: unknown event type \"$e\"\n"
			    unless $e =~
			    /^($cat1pat)\..*[^.]$/;
			die "$name:$line: key repeated: \"$e\"\n"
			    if defined($keys{$e});
			$keys{$e} = 1;
		}
		$maxkey = keys(%keys) if $maxkey < keys(%keys);

		die "$name:$line: duplicate entry for keys\n"
		    if defined($keys2val{$lhs});
		die "$name:$line: duplicate entry for value $rhs\n"
		    if defined($val2keys{$rhs});
		$keys2val{$lhs} = $rhs;
		$val2keys{$rhs} = $lhs;

		open(B, "$buildcode $dname $rhs|") or
		    die "can't run buildcode: $!\n";
		my $code = <B>;
		chomp $code;
		close(B);
		print "code: $code keys: $lhs\n" if $opt_v;
		$code2val{$code} = $rhs;

		if ($opt_p) {
			print <<EOF;
#
# code: $code
# keys: $lhs
#
msgid "$code.type"
msgstr "XXX"
msgid "$code.severity"
msgstr "XXX"
msgid "$code.description"
msgstr "XXX"
msgid "$code.response"
msgstr "XXX"
msgid "$code.impact"
msgstr "XXX"
msgid "$code.action"
msgstr "XXX"
EOF
		}
	}

	print "computed maxkey: $maxkey\n" if $opt_v;

	# check maxkey
	die "$name: maxkey too low, should be $maxkey\n"
	    if $props{'maxkey'} < $maxkey;

	close(F);
}

#
# dobs -- handle backslashed sequences
#
sub dobs {
	my $s = shift;

	return "\n" if $s eq 'n';
	return "\r" if $s eq 'r';
	return "\t" if $s eq 't';
	return $s;
}

#
# dopo -- sanity check a po file
#
sub dopo {
	my $name = shift;
	my $line = 0;
	my $id;
	my $code;
	my $suffix;
	my %ids;

	open(F, $name) or die "$name: $!\n";
	print "parsing \"$name\"\n" if $opt_v;
	while (<F>) {
		$line++;
		next if /^\s*#/;
		chomp;
		next if /^\s*$/;
		next unless /^msgid\s*"([^"]+)"$/;
		$id = $1;
		next unless $id =~
		   /^(.*)\.(type|severity|description|response|impact|action)$/;
		$code = $1;
		$suffix = $2;
		die "$name:$line: no dict entry for code \"$code\"\n"
		   unless defined($code2val{$code});
		$ids{$id} = $line;
	}
	close(F);

	# above checks while reading in file ensured that node code was
	# mentioned in .po file that didn't exist in .dict file.  now
	# check the other direction: make sure the full set of entries
	# exist for each code in the .dict file
	foreach $code (sort keys %code2val) {
		die "$name: missing entry for \"$code.type\"\n"
		    unless defined($ids{"$code.type"});
		die "$name: missing entry for \"$code.severity\"\n"
		    unless defined($ids{"$code.severity"});
		die "$name: missing entry for \"$code.description\"\n"
		    unless defined($ids{"$code.description"});
		die "$name: missing entry for \"$code.response\"\n"
		    unless defined($ids{"$code.response"});
		die "$name: missing entry for \"$code.impact\"\n"
		    unless defined($ids{"$code.impact"});
		die "$name: missing entry for \"$code.action\"\n"
		    unless defined($ids{"$code.action"});
	}
}
#!/bin/ksh -p
#
# CDDL HEADER START
#
# The contents of this file are subject to the terms of the
# Common Development and Distribution License (the "License").
# You may not use this file except in compliance with the License.
#
# You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
# or http://www.opensolaris.org/os/licensing.
# See the License for the specific language governing permissions
# and limitations under the License.
#
# When distributing Covered Code, include this CDDL HEADER in each
# file and include the License file at usr/src/OPENSOLARIS.LICENSE.
# If applicable, add the following below this CDDL HEADER, with the
# fields enclosed by brackets "[]" replaced with your own identifying
# information: Portions Copyright [yyyy] [name of copyright owner]
#
# CDDL HEADER END
#
#
# Copyright 2006 Sun Microsystems, Inc.  All rights reserved.
# Use is subject to license terms.
#

export PATH=/bin:/sbin:/usr/bin:/usr/sbin
unset ENV TMPDIR
umask 022
cwd=$PWD

isa=$(uname -p)
if [[ $isa = sparc ]]; then
	isa64=sparcv9
elif [[ $isa = amd64 || $isa = i386 ]]; then
	isa64=amd64
else
	isa64=unknown
fi

if [[ -n "$CODEMGR_WS" ]]; then
	sysroot=$CODEMGR_WS/proto/root_$isa
elif [[ -n "$ROOT" ]]; then
	sysroot=$ROOT
else
	sysroot=/
fi

quote=
eol='\'
files=

simchan=com.sun:fm:fmd$$
simroot=/tmp/fmd.$$
simscript=run
simpid=

truss_cmd=
truss_args=
dump_args=
inj_args=
fmd_args=

opt_h=false
opt_i=false
opt_s=false
opt_w=false
opt_x=false

function cp_so
{
	nm -ghp $1 2>/dev/null | while read addr type name; do
		[[ $type != T ]] && continue
		case $name in
		_fmd_init)        cp $1 $2/usr/lib/fm/fmd/plugins; return ;;
		fmd_fmri_nvl2str) cp $1 $2/usr/lib/fm/fmd/schemes; return ;;
		topo_load)        cp $1 $2/usr/lib/fm/topo/plugins; return ;;
		esac
	done
	die "\nunknown .so type -- $1"
}

function cp_topo
{
	mkdir -p $2/usr/lib/fm/topo/maps
	cp $1 $2/usr/lib/fm/topo/maps; 
	for platdir in $2/usr/platform/*/lib/fm/topo/maps; do
		rm -f $platdir/* 2>/dev/null
	done
}

function list_cmds
{
	for cmd in fmadm fmdump fmstat; do
		echo usr/sbin/$cmd
	done
}

function wait_status
{
	if [[ $1 -gt 128 ]]; then
		sig=$(kill -l $(($1 - 128)))
		die "fmd terminated from signal $sig (see $simroot)"
	elif [[ $1 -ne 0 ]]; then
		die "fmd terminated with status $1 (see $simroot)"
	fi
}

function wait_prompt
{
	echo "fmsim: [ Press return to $* ] \c"
	mode=$(stty -g)
	stty -echo -isig min 1 time 0
	read s; echo
	stty $mode
}

function die
{
	echo "fmsim: $*" >& 2
	$opt_w && wait_prompt exit
	[[ -n "$simpid" ]] && exit 1 || exit 2
}

while [[ $# -gt 0 ]]; do
	OPTIND=1; while getopts ':d:D:ehio:st:vVwx' c; do
		case "$c" in
		d)
			simroot=$OPTARG
			;;
		D)
			truss_cmd=dtrace
			truss_args="-s $OPTARG -c"
			quote="'"; eol=""
			;;
		e|v|V)
			dump_args="$dump_args -$c"
			;;
		h|i|s|w|x)
			eval opt_$c'='true
			;;
		o)
			fmd_args="$fmd_args -o $OPTARG"
			;;
		t)
			truss_cmd=truss
			truss_args="$OPTARG"
			;;
		:)
			die "option requires an argument -- $OPTARG"
			;;
		*)
			die "illegal option -- $OPTARG"
			;;
		esac
	done
	let OPTIND="$OPTIND - 1"; shift $OPTIND

	if [[ $# -gt 0 ]]; then
		if [[ -d $1 ]]; then
			files="$files $1/*"
		else
			files="$files $1"
		fi
		shift
	fi
done

for file in $files; do
	[[ -r $file ]] || die "input file is missing or not readable -- $file"
done

if $opt_h || [[ -z "$files" && $opt_i = false ]]; then
	echo "Usage: fmsim [-ehisvVwx] [-d dir] [-D a.d] [-o opt=val]" \
	    "[-t args] [file ...]"

	echo "\t-d  set the simulation root directory to the given location"
	echo "\t-D  start fmd(8) using dtrace(8) and specified D script"
	echo "\t-e  display error log content instead of fault log content"
	echo "\t-h  display usage information for fmsim and exit"
	echo "\t-i  set interactive mode: do not stop after sending events"
	echo "\t-o  set fmd(8) option to specified value during simulation"
	echo "\t-s  set up simulation world but do not actually run simulation"
	echo "\t-t  start fmd(8) using truss(1) and specified arguments"
	echo "\t-v  set verbose mode: display additional event detail"
	echo "\t-V  set very verbose mode: display complete event contents"
	echo "\t-w  wait for a keypress after simulation completes"
	echo "\t-x  delete simulation world if simulation is successful"

	exit 0
fi

echo "fmsim: creating simulation world $simroot ... \c"
[[ -d $simroot ]] || mkdir -p $simroot || exit 1
cd $simroot || exit 1
echo "done."

echo "fmsim: populating /var ... \c"
mkdir -p -m 0755 var/fm/fmd
mkdir -p -m 0700 var/fm/fmd/ckpt
mkdir -p -m 0700 var/fm/fmd/rsrc
mkdir -p -m 0700 var/fm/fmd/xprt
echo "done."

echo "fmsim: populating /usr/lib/fm from $sysroot ... \c"
(cd $sysroot && find usr/lib/fm -depth -print | cpio -pdmu $simroot)

for platdir in $sysroot/usr/platform/*/lib/fm; do
	[[ -d $platdir ]] && platdir=${platdir#$sysroot} || continue
	echo "fmsim: populating $platdir from $sysroot ... \c"
	(cd $sysroot && find ${platdir#/} -depth -print | cpio -pdmu $simroot)
done

echo "fmsim: populating /usr/lib/locale/$LANG from $sysroot ... \c"
(cd $sysroot && find usr/lib/locale/$LANG -depth -print | cpio -pdmu $simroot)

echo "fmsim: populating /usr/sbin from $sysroot ... \c"
(cd $sysroot && list_cmds | cpio -pdmu $simroot)

echo "fmsim: adding customizations:\c"
cd $cwd || exit $1

for file in $files; do
	base=$(basename $file)
	case $base in
	*.cmd)	die "\neversholt command file not yet supported -- $file" ;;
	fmd.conf) cp $file $simroot/etc/fm/fmd ;;
	*.conf)	cp $file $simroot/usr/lib/fm/fmd/plugins ;;
	*.dict)	cp $file $simroot/usr/lib/fm/dict ;;
	*.eft) cp $file $simroot/usr/lib/fm/eft ;;
	*.esc)	die "\neversholt source file not yet supported -- $file" ;;
	*.inj)	inj_args="$inj_args $file" ;;
	*.log)	inj_args="$inj_args $file" ;;
	*log)	inj_args="$inj_args $file" ;;
	*.mo)	cp $file $simroot/usr/lib/locale/$LANG/LC_MESSAGES ;;
	*.so)	cp_so $file $simroot ;;
	*.topo) die "\n .topo files not supported -- $file" ;;
	*.xml) cp_topo $file $simroot ;;
	*)	die "\nunknown file type or suffix -- $file" ;;
	esac
	echo " $base\c"
done

cd $simroot || exit 1
echo " done."

echo "fmsim: generating script ... \c"
cat >$simscript <<EOS
#!/bin/ksh -p
#
# Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
# Use is subject to license terms.
#
#ident	"@(#)fmsim.ksh	1.5	06/10/11 SMI"

#
# fmsim(8) script generated for $simroot $(date)
#

export LD_LIBRARY_PATH=$simroot/usr/lib:$simroot/usr/lib/fm
export LD_LIBRARY_PATH_64=$simroot/usr/lib/64:$simroot/usr/lib/fm/$isa64

export _THREAD_ERROR_DETECTION=2

exec $truss_cmd $truss_args $quote./usr/lib/fm/fmd/fmd -R $simroot $eol
    -o fg=true -o clock=simulated $eol
    -o rpc.adm.prog=0 -o rpc.adm.path=$simroot/rpc $eol
    -o sysevent-transport:device=/dev/null $eol
    -o sysevent-transport:channel=$simchan $fmd_args$quote

EOS

chmod 0555 $simscript
echo "done."

if $opt_s; then
	echo "fmsim: simulation is saved in $simroot"
	exit 0
fi

export LD_LIBRARY_PATH=$simroot/usr/lib:$simroot/usr/lib/fm
export LD_LIBRARY_PATH_64=$simroot/usr/lib/64:$simroot/usr/lib/fm/$isa64

echo "fmsim: simulation $$ running fmd(8)\c"
./usr/lib/fm/fmd/fmd -V | cut -d: -f2

./$simscript &
simpid=$!
trap '' INT HUP
cd $cwd
i=0

while [[ ! -s $simroot/rpc ]]; do
	[[ $i -ge 30 ]] && kill -9 $simpid >/dev/null 2>&1
	kill -0 $simpid >/dev/null 2>&1 || break
	let i="$i + 1"
	sleep 1
done

kill -0 $simpid >/dev/null 2>&1 || {
	wait $simpid
	wait_status $?
}

echo "fmsim: rpc adm requests can rendezvous at" $(<$simroot/rpc)
echo "fmsim: injectors should use channel $simchan"
echo "fmsim: debuggers should attach to PID $simpid"

for arg in $inj_args; do
	echo "fmsim: injecting events from $arg ... \c"
	$simroot/usr/lib/fm/fmd/fminject -q -c $simchan $arg || {
		echo "fmsim: fminject failed for $arg: aborting simulation" >& 2
		kill $simpid >/dev/null 2>&1
	}
	echo "done."
done

if [[ $opt_i = false ]]; then
	echo "fmsim: injecting event to advance to end-of-time ... \c"
	echo 'endhrtime;' | $simroot/usr/lib/fm/fmd/fminject -q -c $simchan -
	echo "done."
fi

wait $simpid
status=$?

if [[ -f $simroot/var/fm/fmd/errlog ]]; then
	echo; $simroot/usr/sbin/fmdump -R $simroot $dump_args; echo
fi

wait_status $status
$opt_w && wait_prompt exit
$opt_x && rm -rf $simroot

exit 0